edgetx-companion/PKGBUILD

# Maintainer: lod <aur@cyber-anlage.de>
# Contributer: Ysblokje <ysblokje at gmail dot com>
# Contributer: Jeff Youdontneedtoknow <jeffpublicjr at gmail dot com>
# Contributer: Arnaud

pkgname=edgetx-companion
pkgver=2.9.2
pkgrel=1
pkgdesc="EEPROM Editor and Simulator for EdgeTX RC radio transmitter firmwares"
arch=('x86_64')
url='https://edgetx.org/'
license=('GPL2')
depends=('gcc-libs' 'glibc' 'hicolor-icon-theme' 'qt5-base' 'qt5-multimedia' 'sdl2')
optdepends=('dfu-util: tool for flashing stm32 based radios')
makedepends=('arm-none-eabi-binutils' 'arm-none-eabi-gcc' 'arm-none-eabi-newlib'
             'avr-gcc' 'avr-libc' 'bc' 'clang' 'cmake' 'fox' 'gcc' 'git' 'icu' 'python'
             'python-lz4' 'python-pillow' 'python-pyqt5' 'qt5-svg' 'qt5-tools'
             'qt5-translations' 'sed' 'xsd')
options=('!debug')
provides=('companion')
conflicts=('companion')
source=("git+https://github.com/EdgeTX/edgetx.git#tag=v$pkgver"
        "git+https://github.com/jbeder/yaml-cpp.git"
        "git+https://github.com/raphaelcoeffic/AccessDenied.git"
        "git+https://github.com/FreeRTOS/FreeRTOS-Kernel.git"
        "git+https://github.com/edgetx/libopenui.git"
        "git+https://github.com/FreeRTOS/FreeRTOS-Kernel-Community-Supported-Ports.git"
        "git+https://github.com/FreeRTOS/FreeRTOS-Kernel-Partner-Supported-Ports.git"
        "git+https://github.com/EdgeTX/lvgl.git"
        "git+https://github.com/nothings/stb.git"
        install.patch
        remove-ssl-check.patch)
b2sums=('SKIP'
        'SKIP'
        'SKIP'
        'SKIP'
        'SKIP'
        'SKIP'
        'SKIP'
        'SKIP'
        'SKIP'
        '2f2d110ba03c3d852bec93a0705570df93e72f5e3757bd64494083c5a1ae59c5228024fca563043c05014b1962ccde88e029a6bac2fe36be6e852a53b35a43fb'
        '6ad8cfff9f623c1d0182713839419b633f421e762d01cd46b2ce817c1552929d9ffadcb38f112d6ac9d3d196346b781d842ad0d9c34d4dbe0d5709a3edbc6026')

prepare() {
  _pkgbase=$srcdir/${pkgname%%-*}
  _versuff=${pkgver/./} && _versuff=${_versuff%%.*}
  
  export EDGETX_VERSION_TAG=$pkgver
  
  cd $_pkgbase
   
  patch ./tools/build-companion.sh < $srcdir/install.patch
  patch ./companion/src/CMakeLists.txt < $srcdir/remove-ssl-check.patch
  
  cd $_pkgbase/companion/src/thirdparty/
  git submodule init
  git config submodule.yaml-cpp.url $srcdir/yaml-cpp
  git submodule update --init
  
  cd $_pkgbase/radio/src/thirdparty/
  git submodule init
  git config submodule.AccessDenied.url $srcdir/AccessDenied
  git config submodule.FreeRTOS-Kernel.url $srcdir/FreeRTOS
  git config submodule.libopenui.url $srcdir/libopenui
  git submodule update --init
  
  cd $_pkgbase/radio/src/thirdparty/FreeRTOS/portable/ThirdParty/
  git submodule init
  git config submodule.FreeRTOS-Kernel-Community-Supported-Ports.url $srcdir/Community-Supported-Ports
  git config submodule.FreeRTOS-Kernel-Partner-Supported-Ports.url $srcdir/FreeRTOS-Kernel-Partner-Supported-Ports
  git submodule update --init
  
  cd $_pkgbase/radio/src/thirdparty/libopenui/thirdparty/
  git submodule init
  git config submodule.lvgl.url $srcdir/lvgl
  git config submodule.stb.url $srcdir/stb
  git submodule update --init
}

build() {
  cd $_pkgbase
  ./tools/build-companion.sh $MAKEFLAGS $_pkgbase $srcdir/build $_versuff
}

package() {
  cd $srcdir/build/native
  make DESTDIR=$pkgdir/ install
  cd $pkgdir/usr/share/applications
  sed -i -e 's/Categories=Application/Categories=Utility/' companion$_versuff.desktop
  sed -i -e 's/Categories=Application/Categories=Utility/' simulator$_versuff.desktop
}